PFZ(f,r)$flab(f) = 1 ;
PDAZ(a,i,r)$ay(a,i) = 1;
PFAZ(f,i,r)  =  1+ tf(f,i,r) ;

tFD(i,'PRI',r) = tp(i,r);
tFD(i,'PUB',r) = tg(i,r);
tFD(i,'INV',r) = ti(i,'CPG',r);
PFDZ(i,j,r)  = 1 + tFD(i,j,r) ;

PIMZ(i,r,rr) = (1+tx(i,r,rr))*(1+tm(i,r,rr));
P_IOZ(ii,i,r) =  1+ti(ii,i,r) ;
PTMZ(i,rr,r) = 1+tm(i,rr,r);

dDEP(r) =   vdep(r)/vkb(r) ;

EXRZ(i,r,rr) = vxmd(i,r,rr);
 FDZ(i,'PRI',r) = vdpm(i,r)+vipm(i,r);
 FDZ(i,'PUB',r) = vdgm(i,r)+vigm(i,r);
 FDZ(i,'INV',r) = vafm(i,'CPG',r);
 FDZ(i,j,r)$(FDZ(i,j,r)< 1e-5) = 0;
* Adjust wheat consumed by households in Pakistan based on the updated 2011 data in GTAP10
 FDZ('wht','PRI','PAK') = 3.11 ;      FDZ('fod','PRI','PAK') = FDZ('fod','PRI','PAK') - 3.11 ;

   evh(y,'pri',r)$SUM(j$jpri(j),FDZ(y,j,r)) = edp(y,r) + eip(y,r);
   evh(y,'pub',r)$SUM(j$jpub(j),FDZ(y,j,r)) = edg(y,r) + eig(y,r);
FTOT(f,r) = SUM(y,vfm(f,y,r));
GLOBTRUST = SUM(r,FTOT('CAP',r));
GLOBTRUSTSHARE(r) = FTOT('CAP',r)/GLOBTRUST;
IFZ(f,y,r) = vfm(f,y,r);
IFZ(f,y,r)$(IFZ(f,y,r)<1e-5) = 0 ;

IMZ(i,r) = SUM(rr,EXRZ(i,rr,r));
IMZ(i,r)$(IMZ(i,r)<1e-5)  = 0 ;
IMTOTZ(i,r) = SUM(rr,(EXRZ(i,rr,r)*(1+tx(i,rr,r))+vtwr(i,rr,r))*(1+tm(i,rr,r)));
IMTOTZ(i,r)$(IMTOTZ(i,r)<1e-5)  = 0 ;
INVZ(r)   =  SUM(i,FDZ(i,"INV",r)*PFDZ(i,"INV",r));
IOZ(y,i,r)$(vafm(y,i,r)>10**(-5)) = vafm(y,i,r);
* Adjust wheat consumed by households in Pakistan based on the updated 2011 data in GTAP10
IOZ('wht','fod','PAK') = IOZ('wht','fod','PAK') - 3.11 ;

 evf(y,yy,r)$IOZ(y,yy,r) = edf(y,yy,r) + eif(y,yy,r) ;
 TRNZ(j,r)$jcon(j) =  SUM(i,FDZ(i,j,r)*PFDZ(i,j,r));
  XDZ(i,r) =(SUM(ii,IOZ(ii,i,r)*(1+ti(ii,i,r)))+SUM((f),vfm(f,i,r)*(1+tf(f,i,r))) )/(1-ty(i,r));
  XDZ(i,r)$(XDZ(i,r)<1e-5) = 0 ;
 REGINCZ(r) = SUM(f,FTOT(f,r))
         + SUM((f,i),tf(f,i,r)*IFZ(f,i,r)) + SUM((i,ii),ti(i,ii,r)*IOZ(i,ii,r))
         + SUM((i,j),tFD(i,j,r)*FDZ(i,j,r)) + SUM(i,XDZ(i,r)*ty(i,r))
         + SUM((i,rr),tx(i,r,rr)*EXRZ(i,r,rr)) + SUM((i,rr),(1+tx(i,rr,r)+vtwr(i,rr,r)/vxmd(i,rr,r))*tm(i,rr,r)*EXRZ(i,rr,r)) ;
SAVZ(r) = REGINCZ(r) - SUM(j$jcon(j),TRNZ(j,r));
 VKBZ(r) = vkb(r) ;
 VKEZ(r) = vkb(r) - vdep(r) + INVZ(r);
*ROREZ(r) = (sum(f$fcap(f),FTOT(f,r)) - vdep(r))/VKBZ(r)  ;
TRANRZ(i,r) = vst(i,r);
XZ(i,r) = SUM(ii,IOZ(i,ii,r))+SUM(j,FDZ(i,j,r));
XZ(i,r)$(XZ(i,r)<1e-5) = 0 ;   IMTOTZ(i,r)$(XZ(i,r)=0)  = 0 ;
XDDZ(i,r) = XDZ(i,r) - SUM(rr,EXRZ(i,r,rr)) - vst(i,r)$vst(i,r);
XDDZ(i,r)$(XDDZ(i,r) <1e-5) = 0 ;
 GDPZ(r) =  sum(y,XDZ(y,r) - sum(ii,IOZ(ii,y,r)) )  ;
 FOSSZ(y,r)$ie(y)  =   SUM(i$IOZ(y,i,r),evf(y,i,r)) + sum(j,evh(y,j,r)) ;

* New parameters for dynamic module
SAVINGS(r) = GLOBTRUSTSHARE(r)*sum(rr,vkb(rr)) ;
display vkbz;

PPZ(r) = 0;
PERMITZ(r) = 1 ;

* Set the initial input/output values for each technology/activity. sum up to the values of the produced goods
XDAZ(a,i,r)$(ord(a)=1) = XDZ(i,r) ;
IOAZ(ii,a,i,r)$(ord(a)=1) = IOZ(ii,i,r) ;
IFAZ(f,a,i,r)$(ord(a)=1) = IFZ(f,i,r) ;

gene_gz(a,y,r) = 1;
CAPAZ(a,y,r)   =1 ;

* green bond
INV_noCZ(r) = 0 ;
INV_noCTOTZ = 0 ;
INV_noFZ(r) = 0 ;
INV_noFTOTZ = 0 ;
RORZ(r)= sum(f$fcap(f),FTOT(f,r))/VKBZ(r);
VKBSZ(i, r)$(sum(f$fcap(f),IFZ(f,i,r)) ) = sum(f$fcap(f),IFZ(f,i,r))/ RORZ(r) ;
VKB_noCZ(r)  = sum((f,i)$(fcap(f) and (not icol(i))),IFZ(f,i,r))/ RORZ(r) ;
VKB_noFZ(r)  = sum((f,i)$(fcap(f) and (not ief(i))),IFZ(f,i,r))/ RORZ(r) ;

IF_ABSZ(f,a,y,r) = 0 ;
IO_ABSZ(y,a,yy,r) = 1 ;
FD_ABSZ(y,j,r) = 1 ;

ROREZ(r) = RORZ(r)  ;
RORGFLEX(r) = 10$rchn(r) + 10$(not rchn(r)) ;
KHAT(r) = VKEZ(r)/VKBZ(r) ;
*KHAT(r) = (sum(rr,ROREZ(rr)*VKBZ(rr))/sum(rrr,VKBZ(rrr))/ROREZ(r))**(-1/RORGFLEX(r)) / (VKEZ(r)/VKBZ(r)) ;
display KHAT;