* Production at 300 K
*

! { parameters passed }
set step_lim 3000  ! total number of steps for the production
set step_n 3000  ! number of steps for each restart
$SET$

!size of box (approx)
set 8  93.31
set 9  62.21

! Read in Topology and  Parameter files
open unit 1 card read name @path/lib/top_all22_prot_na.inp
read RTF card unit 1
close unit 1
open unit 1 card read name @path/lib/par_all22_prot_na.inp
read PARA card unit 1
close unit 1

! { psf }
open unit 1 read formatted name @path/scr/@pdb.dyna_solv.psf
read psf card unit 1
close unit 1

! { coordinates IGNORE option required for large systems
! bypasses normal checks and allows very large files to be 
! read in}
OPEN UNIT 1 READ FORMatted NAME @path/scr/@pdb.@inp.crd 
READ COORdinate IGNORE UNIT 1
CLOSE UNIT 1

! use shake
shake bonh para

! build crystal
open unit 8 read card name @path/lib/tip32.img
read imag unit 8
image byres select all end
!image byres select segid A .or. segid L .or. segid M end

! { intialize constraint potential }
!CONStraint HARMonic EXPOnent 2 FORCe 1.0

!SCALar CONStraint = WMAIN ! { unscaled harmonic force-constants }

!cons fix sele segid A .or. segid L end

! energy parameters
energy imgfrq 10 inbfrq 10 cutnb 13.0 cutim 13.0 ctonnb 8.5 ctofnb 12.5 -
  vswitch shift cdie eps 1 !-

!mini sd nstep 250 nprint 10

! md run
open read formatted unit 30 name @path/scr/@pdb.@inp.res
open write formatted unit 31 name @path/scr/@pdb.@out.res
open write unformatted unit 32 name @path/scr/@pdb.@out.cor

! use pgamma 10 for production !
dyna  vver nose qref 50.0 tref @temp.0 ncyc 5 -
      restart nstep @{step_n} timestep 0.001  -
      isvfrq 500 iprfrq 500 nprint 100 -
      iunrea 30 iunwri 31 iuncrd 32 -
      imgfrq 10 inbfrq 10 -
      nsavc 100 -     
      echeck 100 
      
! write out coordinates
OPEN WRITE CARD NAME @path/scr/@pdb.@out.crd UNIT 20
WRITE COOR CARD UNIT 20
*  @job
*  COORdinates 
*

OPEN WRITE CARD NAME @path/scr/@pdb.@out.pdb UNIT 20
WRITE COOR PDB UNIT 20
*  @job
*  COORdinates 
*

STOP