**                                       **
*        Define key parameters for alternative scenarios      *
**                                       **

SET

SIM  simulations
 /
 BAU      base simulation. use resource technical changes based on countries with 2009 data for EU and ROW from WIOD 1995-2009

 SN1      Energy efficiency only happen in 2040 and labor input is activity-specific
 SN2      Energy efficiency only happen in 2040 and full employment in a region where labor freely moves among activities
 SN3      Energy efficiency happen gradually over 2015-2040 and full employment in a region where labor freely moves among activities
 SN4      Energy efficiency happen gradually over 2015-2040 and Unemployment is allowed in a region
 /

 SIMCUR(SIM)     current simulations
 ;

*By defining SIMCUR, the user selects the experiments that are
*carried out. BASE should always be included in SIMCUR.

 SIMCUR(SIM)       = NO;
 SIMCUR('BAU')    = YES;
 SIMCUR('SN2')    = YES;
 SIMCUR(SIM)       = YES;

* Assign initial parameters to all scenarios

* Technical parameters for production functions
Parameter
         eff_xd(a,y,r)  preference change rates of goods (electricity) generated from alternative technologies
         eff(yy,a,y,r) efficiency on intermediate inputs
         eff_if(f,a,y,r) efficiency on primary inputs
         eff_f(*,j,r)  efficiency on consumption goods;

eff_xd(a,i,r)$ay(a,i) = 1 ;
eff(ii,a,i,r) = 1;
eff_if(f,a,i,r) = 1;
eff_f(i,j,r) = 1;

*Next to determin intertemporal parameters for BAU
set age, sex;
parameter
          pop_(r,t,age,sex) population from UN population projection 2010 revision (Thousand)
          popg_(r,t,age,sex) indices of population from UN population projection 2010 revision
          labg_(r,t,sex) indices of population from UN population projection 2010 revision
          pop(r,t) population from UN population projection 2010 revision (Thousand)
          popg(r,t) indices of population from UN population projection 2010 revision
          labg(r,t) indices of population from UN population projection 2010 revision
         ;
$GDXIN pop_un.gdx
$LOAD age,sex,pop_=pop popg_=popg labg_=labg
pop(r,t) = pop_(r,t,'TOT','TOT') / 1000 ;
popg(r,t) = popg_(r,t,'TOT','TOT') - 1 ;
labg(r,t) = labg_(r,t,'TOT') - 1 ;
$GDXIN

parameter
         GDPg(r,t)  GDP growth rates from weo2014
         Prim_eng(y,r,t) primary energy growth rates from weo2014
         ;

$GDXIN weoiaee
$LOAD GDPg
      GDPg(r,t)$(rind(r) and (ord(t)>30) ) = 0.031 ;
      GDPg(r,t)$(rchn(r) and (ord(t)>30) ) = 0.020 ;

$LOAD Prim_eng=TPEDg
$LOAD gene_t
$LOAD gene_g_t
$GDXIN
gene_t(a,y,r,t)$(gene_t(a,y,r,t)<1) = 0 ;
gene_g_t(a,y,r,t)$((gene_t(a,y,r,t)=0) or (gene_t(a,y,r,t-1)=0)) = 0 ;

parameter
GDPgZ(r)     GDP volume index following GDP growth rates form weo2009
EFFTFPZ(f,r)  initial total factor productivity (TFP)
EFFTFP_SZ(f,y,r)  initial total factor productivity (TFP) for natural resources
TS_PrimenZ(y,r)   calibrated tax or subsidy rates for exogenous primary energy path
Prim_enZ(y,r) primary energy indices for weo2014
efftfpz_T(f,r,SIM,tmax)  calibrated TFP
efftfp_sz_T(f,y,r,SIM,tmax) calibrated TFP for natural resources
eghga_abz_T(r,t)  calibrated change rate of initial emissions from intermediate use of energy in sector yy
CAPAZ_T(a,y,r,SIM,tmax)      capacity constraints for elc. generation
TS_PrimenZ_T(y,r,SIM,tmax)   calibrated tax or subsidy rates for exogenous primary energy path
eff_if_T_(f,a,y,r,SIM,tmax)  efficiency on primary factors in production functions

         ;

GDPgZ(r) = 1;
EFFTFPZ(f,r) = 1;
EFFTFP_SZ(f,y,r) = 1;
Prim_enZ(y,r)$(ipep(y) or ielc(y)) = 1;
TS_PrimenZ(i,r) = 0;

$if not exist efftfp.gdx eghga_abz_T(r,t) = 1;
$if not exist efftfp.gdx efftfpz_T(f,r,SIM,t) = 1;
$if not exist efftfp.gdx efftfp_sz_T(f,y,r,SIM,t)$ipep(y) = 1;
$if not exist efftfp.gdx TS_PrimenZ_T(i,r,SIM,t)=0;
$if not exist efftfp.gdx CAPAZ_T(a,y,r,SIM,t) = 0;
$if not exist efftfp.gdx eff_if_T_(f,a,y,r,SIM,tmax) = 1 ;

$if exist efftfp.gdx  $GDXIN efftfp
$if exist efftfp.gdx  $LOAD efftfpz_T
$if exist efftfp.gdx  $LOAD efftfp_sz_T
$if exist efftfp.gdx  $LOAD eghga_abz_T
$if exist efftfp.gdx  $LOAD CAPAZ_T
*         CAPAZ_T(a,y,r,SIM,t)$(ielc(y) and ord(SIM)>1) = CAPAZ_T(a,y,r,'BAU',t);
$if exist efftfp.gdx  $LOAD TS_PrimenZ_T
$if exist efftfp.gdx  $LOAD eff_if_T_
$if exist efftfp.gdx  $GDXIN
display GDPg, Prim_enZ,efftfpz_T,gene_t;

parameter eff_ifg(*,*,r,t,SIM) ;
$GDXIN WIOD_Grace
$LOAD eff_ifg=eff_if
$GDXIN
eff_ifg(ie,i,r,t,SIM)$(ord(t)=1 and (ord(SIM)>1)) = eff_ifg(ie,i,r,t,'BAU')+log(1.1)/25 ;
eff_ifg(ie,'TOT',r,t,SIM)$(ord(t)=1 and (ord(SIM)>1)) = eff_ifg(ie,'TOT',r,t,'BAU')+log(1.1)/25 ;